find and replace in multiple docs...

[ChrisPr]

possible? or asking too much :-)

Thanks
ChrisPr

[HansV]

If you want to replace text in all documents in a folder, you can do so using a VBA macro, for example:

Code: Select all

Sub ProcessFiles()
  ' Edit as needed, but keep trailing backslash
  Const strPath = "C:\Word\"
  Dim strFile As String
  Dim doc As Document

  On Error GoTo ErrHandler

  strFile = Dir(strPath & "*.doc")
  Do While Not strFile = ""
    Set doc = Documents.Open(FileName:=strPath & strFile, AddToRecentFiles:=False)
    With doc.Content.Find
      .ClearFormatting
      .Replacement.ClearFormatting
      ' Change the text as needed
      .Execute FindText:="abc", ReplaceWith:="xyz", Replace:=wdReplaceAll
    End With
    doc.Close SaveChanges:=wdSaveChanges
    strFile = Dir
  Loop

ExitHandler:
  Set doc = Nothing
  Exit Sub

ErrHandler:
  MsgBox Err.Description, vbExclamation
  Resume ExitHandler
End Sub

You could use InputBox to ask the user for the 'Find what' and 'Replace with' text instead of using fixed strings.

[ABabeNChrist]

Hi Hans
shouldnt this line

Code: Select all

 .Execute FindText:="abc", ReplaceWith:="xyz", Replace:=wdReplaceAll\

be

Code: Select all

 .Execute FindText:="abc", ReplaceWith:="xyz", Replace:=wdReplaceAll

[HansV]

Yes, of course. Thank you! (That's what you get if you write air code...)

[ABabeNChrist]

I get lucky every now and then
its been your great teaching skills that has helped me
a few months ago I wouldnt of had a clue

[HansV]

Thanks for your kind words!

[HansV]

For a more flexible solution, you could take a look at Greg Maxey's free add-in VBA Find and Replace.